MetaStock -> Tools -> Indicator Builder -> New
-> copy & paste complete formulae between "---8<---" lines.


=======================
High/Low of Date period
=======================
---8<------------------------------------

{Plots High/Low of user-input date period.

 Copyright © 2004-2008 Jose Silva
 The grant of this license is for personal use
  only - no resale or repackaging allowed.
 All code remains the property of Jose Silva.
 http://www.metastocktools.com }

{ Date inputs }
StDay:=Input("start Day",1,31,1);
StMnth:=Input("start Month",1,12,1);
StYear:=Input("start Year",1800,2200,2006);
EnDay:=Input("end Day",1,31,1);
EnMnth:=Input("end Month",1,12,7);
EnYear:=Input("end Year",1800,2200,2006);

{ Restrict to selected period }
start:=Year()>StYear
 OR (Year()=StYear AND (Month()>StMnth
 OR Month()=StMnth AND DayOfMonth()>=StDay));
end:=Year()<EnYear
 OR (Year()=EnYear AND (Month()<EnMnth
 OR Month()=EnMnth AND DayOfMonth()<=EnDay));

{ High/Low for selected period }
period:=start AND end;
Hi:=Highest(ValueWhen(1,period,H));
Lo:=Lowest(ValueWhen(1,period,L));

{ Enable below to restrict plot to period }
{plot:=LastValue(BarsSince(end));
 Hi:=Ref(Ref(Hi,-plot),plot);
 Lo:=Ref(Ref(Lo,-plot),plot);}

{ Plot on price chart }
Hi;Lo

---8<------------------------------------


=======================
High/Low of Time period
=======================
---8<------------------------------------

{Plots High/Low of intraday time period.

 Copyright © 2004-2008 Jose Silva
 The grant of this license is for personal use
  only - no resale or repackaging allowed.
 All code remains the property of Jose Silva.
 http://www.metastocktools.com }

{ Time inputs }
StHour:=Input("start Hour",0,23,9);
StMin:=Input("start Minute",0,59,0);
EnHour:=Input("last Hour",0,23,12);
EnMin:=Input("last Minute",0,59,0);
plot:=Input("plot:  [1]Hi/Lo,  [2]Time Signals",1,2,1);

{ Time period }
start:=Hour()>StHour
 OR Hour()=StHour AND Minute()>=StMin;
end:=Hour()<EnHour
 OR Hour()=EnHour AND Minute()<=EnMin;
period:=start AND end;

{ Time signals }
start:=period AND Alert(period=0,2)
 OR Cum(period)=1;
end:=Zig(period AND Cum(1)>1,1,$)=1;

{ High/Low for selected period }
Hi:=ValueWhen(1,period,HighestSince(1,start,H));
Lo:=ValueWhen(1,period,LowestSince(1,start,L));

{ Plot on price chart }
If(plot=1,Hi,start);
If(plot=1,Lo,-End)

---8<------------------------------------


http://www.metastocktools.com