MetaStock -> Tools -> Indicator Builder -> New
-> copy & paste formulae below.


==================
Signal accumulator
==================
---8<-----------------------------------------

{ Accumulates OBV/Volume (or any other values)
  between & including two user-input dates.
  http://www.metastocktools.com }

{ Value to accumulate - OBV }
x:=If(C>Ref(C,-1),V,If(C<Ref(C,-1),-V,0));

{ Value to accumulate - Volume }
{x:=V;}

{ Date inputs }
StDay:=Input("Start Day",1,31,1);
StMnth:=Input("start Month",1,12,10);
StYear:=Input("start Year",1960,2060,2003);
EnDay:=Input("End Day",1,31,31);
EnMnth:=Input("end Month",1,12,10);
EnYear:=Input("end Year",1960,2060,2003);

{ Date period }
start:=Year()>StYear
 OR (Year()=StYear AND (Month()>StMnth
  OR Month()=StMnth AND DayOfMonth()>=StDay));
end:=Year()<EnYear
 OR (Year()=EnYear AND (Month()<EnMnth
  OR Month()=EnMnth AND DayOfMonth()<=EnDay));
period:=start AND end;

{ Plot in own window }
If(period,Cum(If(period,x,0)),0)

---8<-----------------------------------------



========================
Signal/Value accumulator
========================
---8<-----------------------------------------

{ Signal/Value accumulator v2.0
  Accumulates & resets values between signals.
  http://www.metastocktools.com }

{ Start count signal }
start:=TroughBars(1,C,5)=0;

{ End count signal }
end:=PeakBars(1,C,5)=0;

{ Value to accumulate - Volume }
value:=V;

{ Indicator output choice }
plot:=Input("plot:   [1]Accumulation,   [2]Signals",1,2,1);

{ Remove redundant interim start/end signals }
init:=Cum(IsDefined(start+end))=1;
flag:=ValueWhen(1,start-end<>0 OR init,start);
start:=flag*(Alert(flag=0,2)
 OR start*Cum(start)=1);
end:=(flag=0)*(Alert(flag,2)
 OR end*Cum(end)=1);

{ Accumulate values }
acc:=Cum(flag*value);
accVal:=acc-ValueWhen(1,end,acc);

{ Plot in own window }
If(plot=1,accVal,start-end)

---8<-----------------------------------------


http://www.metastocktools.com